# SOME EXAMPLE QUERIES TO THE APERTIUM RDF GRAPH
# 
# SPARQL ENDPOINT: http://dbserver.acoli.cs.uni-frankfurt.de:5005/dataset.html?tab=query&ds=/apertium
# at University of Frankfurt
#
# REMOVE the "FROM" line if you are using it on a different SPARQL Endpoint and the data is in the "default graph"
# MODIFY the "FROM" line conveniently if you are using it on a different graph

#-------------------------------------------------
# EXAMPLE 5
# by Jorge Gracia (UNIZAR)
# on Feb 2021
#
# Get all the direct translations belonging to a translation set:
# source and target written representations along with all the 
# intermediate elements and POS 

PREFIX ontolex: <http://www.w3.org/ns/lemon/ontolex#>
PREFIX dc: <http://purl.org/dc/elements/1.1/>
PREFIX tr: <http://www.w3.org/ns/lemon/vartrans#>
PREFIX lime: <http://www.w3.org/ns/lemon/lime#>
PREFIX lexinfo: <http://www.lexinfo.net/ontology/2.0/lexinfo#>
PREFIX rdfs: <http://www.w3.org/2000/01/rdf-schema#>

SELECT DISTINCT ?written_rep_a ?lex_entry_a ?sense_a ?trans ?sense_b ?lex_entry_b ?written_rep_b ?POS
FROM <http://linguistic.linkeddata.es/id/apertium-ud>
WHERE {
  
   
  #determine translation set
  ?trans_set lime:language "en" ;
			 lime:language "es" .
			 
  #retrieve translations
  ?trans_set tr:trans ?trans .
  
  #retrieve source and target senses
  ?trans tr:source ?sense_a ;
		 tr:target ?sense_b .
    
  #retrieve source lexical entry, form and written representation
  ?sense_a ontolex:isSenseOf  ?lex_entry_a .
  ?lex_entry_a ontolex:lexicalForm ?form_a .
  ?form_a ontolex:writtenRep ?written_rep_a .
  
  #retrieve target lexical entry, form and written representation
  ?sense_b ontolex:isSenseOf  ?lex_entry_b .
  ?lex_entry_b ontolex:lexicalForm ?form_b .
  ?form_b ontolex:writtenRep ?written_rep_b .

  #retrieve POS
  ?lex_entry_b  lexinfo:partOfSpeech ?POS .
}